Each of the front motion detectors are monitored by different RF Receivers so they each have different house codes.  There are two motion detectors, one in the driveway and one at the front door.  The drive way detector can see motion (limited) on the street so we also control the Christmas lights with the front timer.  First the motion detector events:

BEGINIF PLC-Button C Is 13/On            ->House Code C, Unit Code 13 (Driveway Motion Detector)
Then Text-A T1<-T1 Text, C13
Then Text-A Set <Space>
Then Text-A T1/A<-Stt PLC-Command C
Then Text-A Set Log/Speak                ->Log and speak about motion detected in driveway
If Daylight Is True                      ->In the daytime
Then Timer, Driveway Set 90              ->Set the driveway timer
Then Timer, Front Set 90                 ->Set the front group timer
If Daylight Is False                     ->After dark
Then Timer, Driveway Set 180             ->Set the driveway timer (notice the timer is set higher)
Then Timer, Front Set 180                ->Set the front group timer (also higher)
ENDIF
;----------------------------------------------------------------
BEGINIF PLC-Button D Is 1/On             ->House Code D, Unit Code 1 (Front Door Motion Detector)
Then Text-A T1<-T1 Text, D1
Then Text-A Set <Space>
Then Text-A T1/A<-Stt PLC-Command D
Then Text-A Set Log/Speak                ->Log and speak about motion detected at Front Door
Then Timer, Front Door Set 181           ->Set front door timer (same day or night)
If Daylight Is True                      ->In the daytime
Then Timer, Front Set 90                 ->Set the front group timer
Else If Daylight Is False                ->After dark
Then Timer, Front Set 180                ->Set the front group timer
ENDIF

Then the timer events.  Just to keep it simple, all these events are stored under one name; "Timer, Front".

;----------------------------------------------------------------
; The first motion detector timer to control the state of the
; motion detector item. We also rattle a couple of lights to
; let someone know there is someone at the front door.
;----------------------------------------------------------------
If Timer, Front Door Is GE 1                ->The first 'if' statement controls the item
Then Motion, Front Door Set On              ->'Motion, Front Door'
Else Motion, Front Door Set Off
If Timer, Front Door Is Now 180             ->When there is someone at the front door,
Then Temp State 1 Set Lt, Ofc, Lamp, Rick   ->we want to know about it if everybody is
Then Lt, Ofc, Lamp, Rick Set Off            ->downstairs watching a movie (this has happened
Then Lt, Ofc, Lamp, Rick Set On             ->several times.  The lamp on my desk is visible
If Timer, Front Door Is Now 179             ->from the theater and provides notification
Then Lt, Ofc, Lamp, Rick Set Off            ->someone is at the door.  First we store the
Then Lt, Ofc, Lamp, Rick Set On             ->current state of that lamp; then we start
If Timer, Front Door Is Now 178             ->flashing it on and off.  When finished we
Then Lt, Ofc, Lamp, Rick Set Off            ->restore the light to its original state.
Then Lt, Ofc, Lamp, Rick Set On
BEGINIF Timer, Front Door Is Now 177
Then Lt, Ofc, Lamp, Rick Set Off
Then Lt, Ofc, Lamp, Rick Set On
Then Lt, Ofc, Lamp, Rick Set Temp State 1
ENDIF
;----------------------------------------------------------------
; The second motion detector timer to control the state of the
; motion detector item.
;----------------------------------------------------------------
If Timer, Driveway Is GE 1                  ->The only thing we do here is control the item
Then Motion, Driveway Set On                ->'Motion, Driveway'
Else Motion, Driveway Set Off
;----------------------------------------------------------------
; And finally the control for the lights with the group timer.
;----------------------------------------------------------------
If Timer, Front Is Now 1                    ->If the group timer reaches 1
Then Rm, Front Set 0                        ->turn off the front lights
Then Event-Call Set Rm, Front
Then Sw, Door, Front Set Off
If Timer, Front Is GT Now 90                ->If the group timer is set above 90 seconds
Then Rm, Front Set 1                        ->turn on the front lights.
Then Event-Call Set Rm, Front